FPGA開発日記

カテゴリ別記事インデックス https://msyksphinz.github.io/github_pages , English Version https://fpgadevdiary.hatenadiary.com/

半導体フロントエンド設計100本ノック (1) Ready/Valid 1-entry FIFO

生成AIの普及により、人間がSystemVerilogを書く機会は激減している。 それでも、「基礎体力」と「ものの考え方」として、何よりエンジニアとしてSystemVerilogは最低限書ける状態を維持しておきたい。

そこで、ChatGPTを利用して、1日1問SystemVerilogやマイクロアーキテクチャの問題を出してもらい解くことにした。 基本的なRTLの書き方そのものというよりは、実際に設計するときに出てくる制御やcorner caseを考える練習をしたい。

第1問はReady/Validインターフェースを持つ1-entry FIFO。

問題

以下のようなインターフェースを持つ1-entry FIFOを作る。

module rv_buffer #(
    parameter int DATA_W = 32
) (
    input  logic              i_clk,
    input  logic              i_rst_n,

    input  logic              i_valid,
    output logic              o_ready,
    input  logic [DATA_W-1:0] i_data,

    output logic              o_valid,
    input  logic              i_ready,
    output logic [DATA_W-1:0] o_data
);

転送成立条件は通常のReady/Validで、入力側は i_valid && o_ready、出力側は o_valid && i_ready とする。FIFOはデータを1個だけ保持できる。

ただし、FIFOがfullであっても、現在保持しているデータが同じサイクルで下流へ出ていくのであれば、新しいデータを同時に受け入れられるようにする。例えば i_valid=1, o_valid=1, i_ready=1 の場合、現在保持しているデータをdownstreamへ送りながら、新しい入力データをFIFOへ格納する。

下流が毎サイクルreadyであれば、パイプラインが流れている間は毎サイクル1データを受け付けられることが要求される。

必要な部品を考える

データを保持するためのバッファはもちろん、現在データをバッファが保持しているかどうかを維持する r_valid が必要だろう。 これをベースに、外部インタフェースの駆動条件、データを受け入れる条件などを考える。

o_validを駆動する条件

o_valid は、バッファが有効なデータを保持していれば1となる。 つまりこれだけでよい。

assign o_valid = r_valid;

o_ready を駆動する条件

o_ready つまりバッファにデータを受け入れる条件は以下のようになるだろう。 1. バッファの中に何もない。 r_valid == 1'b0 2. バッファにデータが存在しているが、outputにより掃ける予定。 r_valid & i_ready したがって、以下のようになるだろう。

// assign o_ready = !r_valid | r_valid & i_ready;
assign o_ready = !r_valid | i_ready;

データの受け入れ条件

これは普通に、これまでの信号を使って、input側がhandshakeが成立すればOKとする。

if (i_valid & o_ready) begin
  r_valid <= 1'b1;
  r_data <= i_data;
end

ちなみに、データが出力されるとr_validが落ちる(または次のデータを受け入れる)ので、別の条件も必要。

if (o_valid & i_ready) begin
    r_valid <= i_valid;
    r_data <= i_data;
end

これをまとめて、こうなる。入力側が受け入れられる場合、o_ready==1となる。 本当に入力があった場合はi_valid(=1'b1)が取り込まれ、r_dataに入力データが入る。

if (o_ready) begin
    r_valid <= i_valid;
    if (i_valid) begin
        r_data <= i_data;
    end
end

RTL

最終的には以下のような構成になる。

module rv_buffer #(
    parameter int DATA_W = 32
) (
    input  logic              i_clk,
    input  logic              i_rst_n,

    input  logic              i_valid,
    output logic              o_ready,
    input  logic [DATA_W-1:0] i_data,

    output logic              o_valid,
    input  logic              i_ready,
    output logic [DATA_W-1:0] o_data
);

logic              r_valid;
logic [DATA_W-1:0] r_data;

assign o_valid = r_valid;
assign o_data  = r_data;

assign o_ready = !r_valid || i_ready;

always_ff @(posedge i_clk or negedge i_rst_n) begin
    if (!i_rst_n) begin
        r_valid <= 1'b0;
    end else begin
        if (o_ready) begin
            r_valid <= i_valid;

            if (i_valid) begin
                r_data <= i_data;
            end
        end
    end
end

endmodule